home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.A.po / FEATURES:BEAGLE / UTIL.CITY.SHK / UTILITY.CITY / INT CONVERTER.int < prev    next >
Text File  |  2000-01-01  |  2KB  |  31 lines
  1. 5 REM ============================    INTEGER->APPLESOFT CONVERTER      BY BERT KERSEY
  2. 6 REM   CREATES A TEXT FILE FOR         EXEC-ING I.B. INTO A.S.!      ============================
  3. 7 REM YOU MUST CORRECT SYNTAX         WHEN THROUGH.
  4. 10 DIM FILE$(40)
  5. 15 QUOTE=130:COLOR= 2
  6. 20 D$="<CTRL-D>":REM (CTRL-D)
  7. 25 PRINT D$;"NOMON C,I,O"
  8. 30 TEXT :CALL -936
  9. 35 PRINT D$;"CATALOG":PRINT 
  10. 40 GOSUB 135:PRINT :PRINT "INT->FP CONVERTER":GOSUB 135:PRINT :PRINT 
  11. 45 INPUT "NAME OF INT PROGRAM: ",FILE$:CALL -936
  12. 50 IF FILE$="" THEN 35
  13. 55 GOSUB 1055
  14. 75 PRINT :PRINT "LOAD ";FILE$
  15. 80 IF  LEN(FILE$)<4 THEN FILE$( LEN(FILE$)+1)="XXX"
  16. 85 FILE$=FILE$(1,4):FILE$( LEN(FILE$)+1)="FILE.AS"
  17. 90 PRINT :PRINT "32766 PRINT D$;'";:GOSUB QUOTE:PRINT "OPEN ";FILE$(1,4);"FILE.AS'";:GOSUB QUOTE
  18. 95 PRINT ":PRINTD$;'";:GOSUB QUOTE:PRINT "WRITE ";FILE$;"'";:GOSUB QUOTE
  19. 100 PRINT ": CALL -936: POKE33,127: LIST 0,32765: PRINT D$;'";:GOSUB QUOTE:PRINT "CLOSE'";:GOSUB QUOTE:PRINT 
  20. 105 PRINT :PRINT "32767 TEXT:CALL-936: PRINT: PRINT'";:GOSUB QUOTE:PRINT " FP'";:GOSUB QUOTE
  21. 110 PRINT ":PRINT: PRINT'";:GOSUB QUOTE:PRINT " EXEC ";FILE$;"'";:GOSUB QUOTE
  22. 115 PRINT ":VTAB 1:END"
  23. 120 PRINT :PRINT "GOTO 32766"
  24. 125 TEXT :VTAB 5:END 
  25. 130 PLOT  PEEK (36),2* PEEK (37):RETURN 
  26. 135 PRINT "--------------------------------------";:RETURN 
  27. 1055  POKE 32,1: POKE 33,39:TAB 2:GOSUB 135
  28. 1060 PRINT "USE THE -> KEY & THE REPT KEY TO TRACE OVER COMMANDS. '";:GOSUB QUOTE:PRINT "RETURN'";:GOSUB QUOTE:PRINT " AFTER EACH."
  29. 1065  POKE 50,63:VTAB 2:TAB 9:PRINT "->";:TAB 22:PRINT "REPT": POKE 50,255:VTAB 4
  30. 1070 GOSUB 135:PRINT :RETURN 
  31.